Esempi di regole di estrazione

// Stiamo cercando una sola istanza
~TenantName
// Trova il nome dell'organizzazione che precede la parola chiave "Tenant"
// e che è separato da essa da non più di tre token
// I token intermedi non devono contenere il nome di un'altra organizzazione
[ t: @NEROrganization ]+ [ ~@NEROrganization ~@kw_Tenant ]{0,3} [ @kw_Tenant ]
=>
TenantName( t );

// La variabile a riceve l'entità denominata Money che non è espressa in cifre
// e non è ancora stata assegnata ad alcuna altra istanza dell'elemento di ricerca Money
[ a: @NERMoney( same ) ~@Money ~/\d+/ ]+
[ br: '(' ]
// Il punto interrogativo indica che le parole "in numbers" sono facoltative
// I simboli ^ e $ indicano che l'intera stringa deve corrispondere all'espressione regolare
// L'opzione i indica che la corrispondenza non fa distinzione tra maiuscole e minuscole
( [ e1: /^in$/i ] [ e2: /^numbers$/i ] [ e3: ':' ]? )?
// La variabile b riceve l'entità denominata Money posizionata all'interno delle parentesi
[ b: @NERMoney( same ) ~@Money ]+
=>
Money( a + br + e1 + e2 + e3 + b );

// Cerca un'intestazione di secondo livello numerata che contenga fino a cinque parole in maiuscolo
// Il numero dell'intestazione può essere trovato come singolo token: 1.1
[ t1: /\d{1,2}\.\d{1,2}/ ] [ t2: <all_letters_capitalized> ]{1,5}
=>
kw_Heading2( t1 + t2 );
// Il numero dell'intestazione può essere trovato come tre token separati: 1, punto, 1
[ t1: /\d{1,2}/ ] [ t2: '.' ] [ t3: /\d{1,2}/ ] [ t4: <all_letters_capitalized> ]{1,5}
=>
kw_Heading2( t1 + t2 + t3 + t4 );

// Trova il segmento di testo tra due intestazioni di sezione consecutive
// Escludi anche eventuali intestazioni di primo livello
[ @kw_Heading2 ] [ interval: ~@kw_Heading2 ~@kw_Heading1 ]+
=>
Root.Segment( interval );

// Trova il nome dell'organizzazione e crea una nuova istanza di gruppo per ciascuna
[ org: @NEROrganization( same ) ~@Party_Group.Organization_Name @Parties_Segment ]+
=>
// Crea una nuova istanza di Party_Group e inserisci Organization_Name
Party_Group.Organization_Name( org );

// Ora cerca l'indirizzo separato da non più di 20 token
// dal nome dell'organizzazione
// e che non è ancora stato assegnato ad alcuna organizzazione in Party_Group
[ org: @Party_Group.Organization_Name( same ) ]+
[ ~@NERAddress ]{0,20}
[ t: @NERAddress( same ) ~@Party_Group.Address @Parties_Segment ]+
=>
// Accedi all'istanza di Party_Group che è il padre del nome dell'organizzazione
// e compila il suo elemento figlio Address
parent( obj( org )).Address( t );

// Ripetere la stessa operazione per il ruolo
// Per trovare il ruolo, utilizzare parole chiave
[ org: @Party_Group.Organization_Name( same ) ]+
[ ~("Tenant" | "Landlord" | "Broker") ]{0,20}
[ t: "Tenant" | "Landlord" | "Broker" ~@Party_Group.Role @Parties_Segment ]+
=>
parent( obj( org )).Role( t );

// Utilizza un valore dall'elemento di ricerca con espressione regolare per trovare l'ora
// Utilizza @NERDate per trovare un'entità denominata Date vicina all'ora
[ time: @Time ~@TimeAndDate ]+ [ t: ~@NERDate ]{0,3} [ date: @NERDate( same ) ]+
=>
// Combina i valori per scriverli in un unico field
// Solo le sequenze di token consecutive possono essere combinate, quindi viene aggiunto anche il token ausiliario
TimeAndDate( time + t + date );