Exemples de règles d'extraction

// Nous recherchons une seule instance
~TenantName
// Rechercher le nom d'organisation qui apparaît avant le mot-clé "Tenant"
// et qui en est séparé par trois jetons au maximum
// Les jetons intermédiaires ne doivent pas contenir d'autre nom d'organisation
[ t: @NEROrganization ]+ [ ~@NEROrganization ~@kw_Tenant ]{0,3} [ @kw_Tenant ]
=>
TenantName( t );

// La variable a reçoit l'entité nommée Money qui n'est pas en chiffres
// et qui n'a pas encore été affectée à une autre instance de l'élément de recherche Money
[ a: @NERMoney( same ) ~@Money ~/\d+/ ]+
[ br: '(' ]
// Le point d'interrogation signifie que les mots « en chiffres » sont facultatifs
// Les symboles ^ et $ signifient que la chaîne entière doit correspondre à l'expression régulière
// L'option i signifie que la correspondance ne tient pas compte de la casse
( [ e1: /^in$/i ] [ e2: /^numbers$/i ] [ e3: ':' ]? )?
// La variable b reçoit l'entité nommée Money qui est placée entre parenthèses
[ b: @NERMoney( same ) ~@Money ]+
=>
Money( a + br + e1 + e2 + e3 + b );

// Rechercher un titre de deuxième niveau numéroté contenant jusqu'à cinq mots en majuscules
// Le numéro du titre peut être trouvé sous la forme d'un seul jeton : 1.1
[ t1: /\d{1,2}\.\d{1,2}/ ] [ t2: <all_letters_capitalized> ]{1,5}
=>
kw_Heading2( t1 + t2 );
// Le numéro du titre peut être trouvé sous la forme de trois jetons distincts : 1, point, 1
[ t1: /\d{1,2}/ ] [ t2: '.' ] [ t3: /\d{1,2}/ ] [ t4: <all_letters_capitalized> ]{1,5}
=>
kw_Heading2( t1 + t2 + t3 + t4 );

// Trouver le segment de texte entre deux titres de section consécutifs
// Exclure également les titres de premier niveau
[ @kw_Heading2 ] [ interval: ~@kw_Heading2 ~@kw_Heading1 ]+
=>
Root.Segment( interval );

// Rechercher le nom de l'organisation et créer une nouvelle instance de groupe pour chacune
[ org: @NEROrganization( same ) ~@Party_Group.Organization_Name @Parties_Segment ]+
=>
// Créer une nouvelle instance de Party_Group et renseigner Organization_Name
Party_Group.Organization_Name( org );

// Rechercher maintenant l'adresse séparée par 20 jetons maximum
// du nom de l'organisation
// et qui n'a pas encore été attribuée à l'une des organisations dans Party_Group
[ org: @Party_Group.Organization_Name( same ) ]+
[ ~@NERAddress ]{0,20}
[ t: @NERAddress( same ) ~@Party_Group.Address @Parties_Segment ]+
=>
// Accéder à l'instance de Party_Group qui est le parent du nom de l'organisation
// et renseigner son enfant Address
parent( obj( org )).Address( t );

// Répéter la même opération pour le rôle
// Pour trouver le rôle, utiliser des mots-clés
[ org: @Party_Group.Organization_Name( same ) ]+
[ ~("Tenant" | "Landlord" | "Broker") ]{0,20}
[ t: "Tenant" | "Landlord" | "Broker" ~@Party_Group.Role @Parties_Segment ]+
=>
parent( obj( org )).Role( t );

// Utiliser une valeur de l'élément de recherche par expression régulière pour trouver l'heure
// Utiliser @NERDate pour trouver une entité nommée Date proche de l'heure
[ time: @Time ~@TimeAndDate ]+ [ t: ~@NERDate ]{0,3} [ date: @NERDate( same ) ]+
=>
// Combiner les valeurs pour les écrire dans un seul champ
// Seules les séquences de jetons consécutives peuvent être combinées, le jeton auxiliaire est donc également ajouté
TimeAndDate( time + t + date );