Reglas de extracción de ejemplo

// Buscamos solo una instancia
~TenantName
// Buscar el nombre de la organización que aparece antes de la palabra clave "Tenant"
// y que esté separado de ella por no más de tres tokens
// Los tokens intermedios no deben contener el nombre de otra organización
[ t: @NEROrganization ]+ [ ~@NEROrganization ~@kw_Tenant ]{0,3} [ @kw_Tenant ]
=>
TenantName( t );

// La variable a recibe la entidad nombrada Money que no está en números
// y aún no ha sido asignada a ninguna otra instancia del elemento de búsqueda Money
[ a: @NERMoney( same ) ~@Money ~/\d+/ ]+
[ br: '(' ]
// El signo de interrogación significa que las palabras "in numbers" son opcionales
// Los símbolos ^ y $ significan que toda la cadena debe coincidir con la expresión regular
// La opción i significa que la coincidencia no distingue entre mayúsculas y minúsculas
( [ e1: /^in$/i ] [ e2: /^numbers$/i ] [ e3: ':' ]? )?
// La variable b recibe la entidad nombrada Money que está colocada dentro de corchetes
[ b: @NERMoney( same ) ~@Money ]+
=>
Money( a + br + e1 + e2 + e3 + b );

// Buscar un encabezado de segundo nivel numerado que tenga hasta cinco palabras en mayúsculas
// El número de encabezado se puede encontrar como un solo token: 1.1
[ t1: /\d{1,2}\.\d{1,2}/ ] [ t2: <all_letters_capitalized> ]{1,5}
=>
kw_Heading2( t1 + t2 );
// El número de encabezado se puede encontrar como tres tokens separados: 1, punto, 1
[ t1: /\d{1,2}/ ] [ t2: '.' ] [ t3: /\d{1,2}/ ] [ t4: <all_letters_capitalized> ]{1,5}
=>
kw_Heading2( t1 + t2 + t3 + t4 );

// Encuentra el segmento de texto entre dos encabezados de sección consecutivos
// Excluye también los encabezados de primer nivel
[ @kw_Heading2 ] [ interval: ~@kw_Heading2 ~@kw_Heading1 ]+
=>
Root.Segment( interval );

// Buscar el nombre de la organización y crear una nueva instancia de grupo para cada una
[ org: @NEROrganization( same ) ~@Party_Group.Organization_Name @Parties_Segment ]+
=>
// Crear una nueva instancia de Party_Group y completar Organization_Name
Party_Group.Organization_Name( org );

// Ahora buscar la dirección que esté separada por no más de 20 tokens
// del nombre de la organización
// y que aún no haya sido asignada a ninguna de las organizaciones en Party_Group
[ org: @Party_Group.Organization_Name( same ) ]+
[ ~@NERAddress ]{0,20}
[ t: @NERAddress( same ) ~@Party_Group.Address @Parties_Segment ]+
=>
// Acceder a la instancia de Party_Group que es el elemento principal del nombre de la organización
// y completar su elemento secundario Address
parent( obj( org )).Address( t );

// Repetir lo mismo para el rol
// Para encontrar el rol, utilice palabras clave
[ org: @Party_Group.Organization_Name( same ) ]+
[ ~("Tenant" | "Landlord" | "Broker") ]{0,20}
[ t: "Tenant" | "Landlord" | "Broker" ~@Party_Group.Role @Parties_Segment ]+
=>
parent( obj( org )).Role( t );

// Usar un valor del elemento de búsqueda de expresión regular para encontrar la hora
// Usar @NERDate para encontrar una entidad nombrada de fecha cercana a la hora
[ time: @Time ~@TimeAndDate ]+ [ t: ~@NERDate ]{0,3} [ date: @NERDate( same ) ]+
=>
// Combinar los valores para escribirlos en un campo
// Solo se pueden combinar secuencias de tokens consecutivas, por lo que también se agrega el token auxiliar
TimeAndDate( time + t + date );