抽出ルールのサンプル

// 1つのインスタンスのみを検索
~TenantName
// キーワード「Tenant」の前に出現する組織名を検索
// キーワードとの間隔は3トークン以内
// 間にあるトークンに別の組織名を含めないこと
[ t: @NEROrganization ]+ [ ~@NEROrganization ~@kw_Tenant ]{0,3} [ @kw_Tenant ]
=>
TenantName( t );

// 変数 a は、数字ではない Money 名前付きエンティティを受け取り、
// まだ Money 検索要素の他のインスタンスに割り当てられていないもの
[ a: @NERMoney( same ) ~@Money ~/\d+/ ]+
[ br: '(' ]
// 疑問符は、「in numbers」という単語がオプションであることを意味します
// ^ と $ 記号は、文字列全体が正規表現に一致する必要があることを意味します
// i オプションは、大文字と小文字を区別しない一致を意味します
( [ e1: /^in$/i ] [ e2: /^numbers$/i ] [ e3: ':' ]? )?
// 変数 b は、括弧内に配置された Money 名前付きエンティティを受け取ります
[ b: @NERMoney( same ) ~@Money ]+
=>
Money( a + br + e1 + e2 + e3 + b );

// 最大5単語の全て大文字で構成された番号付き第2レベル見出しを検索
// 見出し番号は1つのトークンとして検出される可能性があります: 1.1
[ t1: /\d{1,2}\.\d{1,2}/ ] [ t2: <all_letters_capitalized> ]{1,5}
=>
kw_Heading2( t1 + t2 );
// 見出し番号は3つの別々のトークンとして検出される可能性があります: 1、ドット、1
[ t1: /\d{1,2}/ ] [ t2: '.' ] [ t3: /\d{1,2}/ ] [ t4: <all_letters_capitalized> ]{1,5}
=>
kw_Heading2( t1 + t2 + t3 + t4 );

// 連続する2つのセクション見出し間のテキストセグメントを検索
// 第1レベルの見出しも除外
[ @kw_Heading2 ] [ interval: ~@kw_Heading2 ~@kw_Heading1 ]+
=>
Root.Segment( interval );

// 組織名を検索し、各組織に対して新しいグループインスタンスを作成
[ org: @NEROrganization( same ) ~@Party_Group.Organization_Name @Parties_Segment ]+
=>
// Party_Groupの新しいインスタンスを作成し、Organization_Nameに入力
Party_Group.Organization_Name( org );

// 次に、組織名から20トークン以内に位置する住所を検索します
// この住所はまだParty_Group内のいずれの組織にも割り当てられていないものです
// 
[ org: @Party_Group.Organization_Name( same ) ]+
[ ~@NERAddress ]{0,20}
[ t: @NERAddress( same ) ~@Party_Group.Address @Parties_Segment ]+
=>
// 組織名の親であるParty_Groupのインスタンスにアクセスし
// そのAddressの子要素を入力します
parent( obj( org )).Address( t );

// ロールについても同様に繰り返す
// ロールを検索するには、キーワードを使用する
[ org: @Party_Group.Organization_Name( same ) ]+
[ ~("Tenant" | "Landlord" | "Broker") ]{0,20}
[ t: "Tenant" | "Landlord" | "Broker" ~@Party_Group.Role @Parties_Segment ]+
=>
parent( obj( org )).Role( t );

// 正規表現検索要素のValueを使用して時刻を検索
// @NERDateを使用して時刻に近いDate名前付きエンティティを検索
[ time: @Time ~@TimeAndDate ]+ [ t: ~@NERDate ]{0,3} [ date: @NERDate( same ) ]+
=>
// 値を結合して1つのfieldに書き込む
// 連続したトークンシーケンスのみ結合可能なため、補助トークンも追加
TimeAndDate( time + t + date );